subroutine write_file(self, file, form, iostat, iomsg)
!< Write a single string stream into file.
!<
!< @note For unformatted read only `access='stream'` is supported with new_line as line terminator.
!<
!<```fortran
!< type(string) :: astring
!< type(string) :: anotherstring
!< type(string), allocatable :: strings(:)
!< type(string) :: line(3)
!< integer :: iostat
!< character(len=99) :: iomsg
!< integer :: scratch
!< integer :: l
!< logical :: test_passed(8)
!< line(1) = ' Hello World! '
!< line(2) = 'How are you? '
!< line(3) = ' All say: "Fine thanks"'
!< anotherstring = anotherstring%join(array=line, sep=new_line('a'))
!< call anotherstring%write_file(file='write_file_test.tmp', iostat=iostat, iomsg=iomsg)
!< call astring%read_file(file='write_file_test.tmp', iostat=iostat, iomsg=iomsg)
!< call astring%split(tokens=strings, sep=new_line('a'))
!< test_passed(1) = (size(strings, dim=1)==size(line, dim=1))
!< do l=1, size(strings, dim=1)
!< test_passed(l+1) = (strings(l)==line(l))
!< enddo
!< call anotherstring%write_file(file='write_file_test.tmp', form='unformatted', iostat=iostat, iomsg=iomsg)
!< call astring%read_file(file='write_file_test.tmp', form='unformatted', iostat=iostat, iomsg=iomsg)
!< call astring%split(tokens=strings, sep=new_line('a'))
!< test_passed(5) = (size(strings, dim=1)==size(line, dim=1))
!< do l=1, size(strings, dim=1)
!< test_passed(l+5) = (strings(l)==line(l))
!< enddo
!< open(newunit=scratch, file='write_file_test.tmp')
!< close(unit=scratch, status='delete')
!< print '(L1)', all(test_passed)
!<```
!=> T <<<
class(string), intent(in) :: self !< The string.
character(len=*), intent(in) :: file !< File name.
character(len=*), intent(in), optional :: form !< Format of unit.
integer, intent(out), optional :: iostat !< IO status code.
character(len=*), intent(inout), optional :: iomsg !< IO status message.
type(string) :: form_ !< Format of unit, local variable.
integer :: iostat_ !< IO status code, local variable.
character(len=:), allocatable :: iomsg_ !< IO status message, local variable.
integer :: unit !< Logical unit.
iomsg_ = repeat(' ', 99) ; if (present(iomsg)) iomsg_ = iomsg
form_ = 'FORMATTED' ; if (present(form)) form_ = form ; form_ = form_%upper()
select case(form_%chars())
case('FORMATTED')
open(newunit=unit, file=file, action='WRITE', iomsg=iomsg_, iostat=iostat_, err=10)
case('UNFORMATTED')
open(newunit=unit, file=file, action='WRITE', form='UNFORMATTED', access='STREAM', iomsg=iomsg_, iostat=iostat_, err=10)
endselect
call self%write_lines(unit=unit, form=form, iomsg=iomsg_, iostat=iostat_)
10 close(unit)
if (present(iostat)) iostat = iostat_
if (present(iomsg)) iomsg = iomsg_
endsubroutine write_file